Clojure

Clojure (/ˈkloʊʒər/, like closure)^[13] is a modern, dynamic, and functional dialect of the Lisp programming language on the Java platform.^[14][15] Like other Lisps, Clojure treats code as data and has a Lisp macro system.^[16] The current development process is community-driven,^[17] overseen by Rich Hickey as its benevolent dictator for life (BDFL).^[18]

Clojure advocates immutability and immutable data structures and encourages programmers to be explicit about managing identity and its states.^[19] This focus on programming with immutable values and explicit progression-of-time constructs is intended to facilitate developing more robust programs, especially multithreaded ones.^[20][21] While its type system is entirely dynamic, recent efforts have also sought the implementation of gradual typing.^[22]

Commercial support for Clojure is provided by Cognitect.^[23] Annual Clojure conferences are organised every year across the globe, the most famous of them being Clojure/conj (US east coast),^[24] Clojure/West (US west coast),^[25] and EuroClojure (Europe).^[26]

History and development process

Rich Hickey, creator of Clojure

Rich Hickey is the creator of the Clojure language.^[14] Before Clojure, he developed dotLisp, a similar project based on the .NET platform,^[27] and three earlier attempts to provide interoperability between Lisp and Java: a Java foreign language interface for Common Lisp (jfli),^[28] A Foreign Object Interface for Lisp (FOIL),^[29] and a Lisp-friendly interface to Java Servlets (Lisplets).^[30]

Hickey spent about 2½ years working on Clojure before releasing it publicly, much of that time working exclusively on Clojure with no outside funding. At the end of this time, Hickey sent an email announcing the language to some friends in the Common Lisp community.

The development process is community-driven^[17] and is managed at the Clojure Community website.^[31] The website contains planning documents and an issue tracker where bugs may be filed. General development discussion occurs at the Clojure Dev Google Group.^[32] Anyone can submit bug reports and ideas, but to contribute patches, one must sign the Clojure Contributor agreement.^[33] JIRA tickets are processed by a team of screeners and finally Rich Hickey approves the changes.^[34]

Design philosophy

Rich Hickey developed Clojure because he wanted a modern Lisp for functional programming, symbiotic with the established Java platform, and designed for concurrency.^[20][21][35]

Clojure's approach to state is characterized by the concept of identities,^[36] which are represented as a series of immutable states over time. Since states are immutable values, any number of workers can operate on them in parallel, and concurrency becomes a question of managing changes from one state to another. For this purpose, Clojure provides several mutable reference types, each having well-defined semantics for the transition between states.^[19][36]

Features

Clojure runs on the Java platform and as a result, integrates with Java and fully supports calling Java code from Clojure,^[49] and Clojure code can be called from Java also.^[50] The community uses Leiningen^[51] for project automation, providing support for Maven integration. Leiningen handles project package management and dependencies and is configured using Clojure syntax.^[51]

Like most other Lisps, Clojure's syntax is built on S-expressions that are first parsed into data structures by a reader before being compiled.^[52] Clojure's reader supports literal syntax for maps, sets and vectors in addition to lists, and these are compiled to the mentioned structures directly.^[52] Clojure is a Lisp-1 and is not intended to be code-compatible with other dialects of Lisp, since it uses its own set of data structures incompatible with other Lisps.^[52][53]

As a Lisp dialect, Clojure supports functions as first-class objects, a read–eval–print loop (REPL), and a macro system.^[54] Clojure's Lisp macro system is very similar to that in Common Lisp with the exception that Clojure's version of the backquote (termed "syntax quote") qualifies symbols with their namespace. This helps prevent unintended name capture, as binding to namespace-qualified names is forbidden. It is possible to force a capturing macro expansion, but it must be done explicitly. Clojure does not allow user-defined reader macros, but the reader supports a more constrained form of syntactic extension.^[55] Clojure supports multimethods^[56] and for interface-like abstractions has a protocol^[57] based polymorphism and data type system using records,^[58] providing high-performance and dynamic polymorphism designed to avoid the expression problem.

Clojure has support for lazy sequences and encourages the principle of immutability and persistent data structures. As a functional language, emphasis is placed on recursion and higher-order functions instead of side-effect-based looping. Automatic tail call optimization is not supported as the JVM does not support it natively;^[59][60][61] it is possible to do so explicitly by using the recur keyword.^[62] For parallel and concurrent programming Clojure provides software transactional memory,^[63] a reactive agent system,^[64] and channel-based concurrent programming.^[65]

Clojure 1.7 introduced reader conditionals by allowing the embedding of Clojure and ClojureScript code in the same namespace.^[44][66] Transducers were added as a method for composing transformations. Transducers enable higher-order functions such as map and fold to generalize over any source of input data. While traditionally these functions operate on sequences, transducers allow them to work on channels and let the user define their own models for transduction.^[67][68][69]

Platforms

The primary platform of Clojure is Java,^[15][49] but other target implementations exist. The most notable of these are ClojureScript,^[70] which compiles to ECMAScript 3,^[71] and ClojureCLR,^[72] a full port on the .NET platform, interoperable with its ecosystem. A survey of the Clojure community with 1,060 respondents conducted in 2013^[73] found that 47% of respondents used both Clojure and ClojureScript when working with Clojure. In 2014 this number had increased to 55%,^[74] in 2015, based on 2,445 respondents, to 66%.^[75] Popular ClojureScript projects include implementations of the React library such as Reagent^[76] and Om.^[77][78]

Popularity

With the continued interest in functional programming, Clojure's adoption by the software developers on the Java platform has kept increasing. The language has also been either preferred or recommended by renowned software development veterans such as James Gosling,^[79] Paul Graham,^[80] and Robert C. Martin (also known as “Uncle Bob”.)^[81]

In the "JVM Ecsosystem Report 2018" (which was claimed to be "the largest survey ever of Java developers"), prepared in collaboration by Snyk and Java Magazine, Clojure was ranked the 2nd most used programming language (behind Java) for "main applications".^[82]

Clojure is used in industry by firms^[83] such as Apple,^[84][85] Atlassian,^[86] Funding Circle,^[87] Netflix,^[88] Puppet,^[89] and Walmart^[90] as well as government agencies such as NASA^[91]. It has also been used for creative computing, including visual art, music, games, and poetry.^[92]

ThoughtWorks, while assessing functional programming languages for their Technology Radar,^[93] expressed their favor toward Clojure as "a simple, elegant implementation of Lisp on the JVM" in 2010 and promoted its status to "ADOPT" in 2012.^[94]

A growing number of unofficial and experimental implementations for other platforms testify to the popularity of the language:

• las3r,^[95] a subset of Clojure that runs on the ActionScript Virtual Machine (the Adobe Flash Player platform)
• clojure-py,^[96] Clojure in pure Python
• rouge,^[97] Clojure atop YARV in Ruby
• CljPerl,^[98] Clojure atop Perl
• Pixie, Clojure-inspired Lisp dialect written in RPython
• Ferret,^[99] compiles to self-contained C++11 that can run on microcontrollers
• Joker,^[100] an interpreter and linter written in Go
• clojerl,^[101] Clojure on the Erlang VM

Tools

Tooling for Clojure development has seen significant improvement over the years. The following is a list of the most popular IDEs/editors with their plug-ins that combined provide excellent support for Clojure development:^[102]

• Emacs, with CIDER^[103]
• IntelliJ IDEA, with Clojure-Kit^[104] or Cursive^[105] (a free, non-commercial license is available)
• Vim, with fireplace.vim^[106]
• Visual Studio Code, with Calva^[107]
• Light Table

In addition to the tools provided by the community, the official CLI tools have also become available on GNU/Linux, macOS, and Windows since Clojure 1.9^[108]

Examples

Hello, World! program

(println "Hello, World!")

Programming at REPL

Like other Lisps, one of the iconic features of Clojure is interactive programming at the REPL.^[109] Note that, in the following examples, ";;" starts a line comment and ";; =>" indicates output:

;; define a var
(def a 42)
;; => #'user/a

;; call a function named `+`
(+ a 8)
;; => 50

;; call a function named `even?`
(even? a)
;; => true

;; define a function that returns the remainder of `n` when divided by 10
(defn foo [n] (rem n 10))
;; => #'user/foo

;; call the function
(foo a)
;; => 2

;; print the docstring of `rem`
(doc rem)
;; =>
-------------------------
clojure.core/rem
([num div])
 remainder of dividing numerator by denominator.

;; print the source of `rem`
(source rem)
;; =>
(defn rem
  "remainder of dividing numerator by denominator."
  {:added "1.0"
   :static true
   :inline (fn [x y] `(. clojure.lang.Numbers (remainder ~x ~y)))}
  [num div]
    (. clojure.lang.Numbers (remainder num div)))

Names at runtime

Unlike other runtime environments where names get compiled away, Clojure's runtime environment is easily introspectable using normal Clojure data structures:

;; define a var
(def a 42)
;; => #'user/a

;; get a map of all public vars interned in the `user` namespace
(ns-publics 'user)
;; => {a #'user/a}

;; reference the var via `#'` (reader macro) and
;; its associated, namespace-qualified symbol `user/a`
#'user/a
;; => #'user/a

;; de-reference (get the value of) the var
(deref #'user/a)
;; => 42

;; define a function (with a docstring) that
;; returns the remainder of `n` when divided by 10
(defn foo "returns `(rem n 10)`" [n] (rem n 10))
;; => #'user/foo

;; get the metadata of the var `#'user/foo`
(meta #'user/foo)
;; =>
{:arglists ([n]),
 :doc "returns `(rem n 10)`",
 :line 1,
 :column 1,
 :file "user.clj",
 :name foo,
 :ns #namespace[user]}

Code as data (homoiconicity)

Similar to other Lisps, Clojure is homoiconic (also known as code as data). In the example below, we can see how easy it is to write code that modifies code itself:

;; call a function (code)
(+ 1 1)
;; => 2

;; quote the function call
;; (turning code into data, which is a list of symbols)
(quote (+ 1 1))
;; => (+ 1 1)

;; get the first element on the list
;; (operating on code as data)
(first (quote (+ 1 1)))
;; => +

;; get the last element on the list
;; (operating on code as data)
(last (quote (+ 1 1)))
;; => 1

;; get a new list by replacing the symbols on the original list
;; (manipulating code as data)
(map (fn [form]
       (case form
         1 'one
         + 'plus))
     (quote (+ 1 1)))
;; => (plus one one)

Expressive operators for data transformation

The threading macros (->, ->>, and friends) can syntactically express the abstraction of piping a collection of data through a series of transformations:

(->> (range 10)
     (map inc)
     (filter even?))
;; => (2 4 6 8 10)

This can also be achieved more efficiently using transducers:

(sequence (comp (map inc)
                (filter even?))
          (range 10))
;; => (2 4 6 8 10)

Thread-safe management of identity and state

A thread-safe generator of unique serial numbers (though, like many other Lisp dialects, Clojure has a built-in gensym function that it uses internally):

(def i (atom 0))

(defn generate-unique-id
  "Returns a distinct numeric ID for each call."
  []
  (swap! i inc))

Macros

An anonymous subclass of java.io.Writer that doesn't write to anything, and a macro using it to silence all prints within it:

(def bit-bucket-writer
  (proxy [java.io.Writer] []
    (write [buf] nil)
    (close []    nil)
    (flush []    nil)))

(defmacro noprint
  "Evaluates the given `forms` with all printing to `*out*` silenced."
  [& forms]
  `(binding [*out* bit-bucket-writer]
     ~@forms))

(noprint
  (println "Hello, nobody!"))
;; => nil

Language interoperability with Java

Clojure was created from ground up to embrace its host platforms as one of its design goals thus provides excellent language interoperability with Java:

;; call an instance method
(.toUpperCase "apple")
;; => "APPLE"

;; call a static method
(System/getProperty "java.vm.version")
;; => "12+33"

;; create an instance of `java.util.HashMap` and
;; add some entries
(doto (java.util.HashMap.)
  (.put "apple" 1)
  (.put "banana" 2))
;; => {"banana" 2, "apple" 1}

;; create an instance of `java.util.ArrayList` and
;; increment its elements with `clojure.core/map`
(def al (doto (java.util.ArrayList.)
          (.add 1)
          (.add 2)
          (.add 3)))

(map inc al)
;; => (2 3 4)

;; show a message dialog using Java Swing
(javax.swing.JOptionPane/showMessageDialog
  nil
  "Hello, World!")
;; => nil

Software transactional memory

10 threads manipulating one shared data structure, which consists of 100 vectors each one containing 10 (initially sequential) unique numbers. Each thread then repeatedly selects two random positions in two random vectors and swaps them. All changes to the vectors occur in transactions by making use of Clojure's software transactional memory system:

(defn run
  [nvecs nitems nthreads niters]
  (let [vec-refs
        (->> (* nvecs nitems)
             (range)
             (into [] (comp (partition-all nitems)
                            (map vec)
                            (map ref))))

        swap
        #(let [v1 (rand-int nvecs)
               v2 (rand-int nvecs)
               i1 (rand-int nitems)
               i2 (rand-int nitems)]
          (dosync
            (let [tmp (nth @(vec-refs v1) i1)]
              (alter (vec-refs v1) assoc i1 (nth @(vec-refs v2) i2))
              (alter (vec-refs v2) assoc i2 tmp))))

        report
        #(->> vec-refs
              (into [] (comp (map deref)
                             (map (fn [v] (prn v) v))
                             cat
                             (distinct)))
              (count)
              (println "Distinct:"))]

    (report)

    (->> #(dotimes [_ niters] (swap))
         (repeat nthreads)
         (apply pcalls)
         (dorun))

    (report)))

(run 100 10 10 100000)
;; =>
[0 1 2 3 4 5 6 7 8 9]
[10 11 12 13 14 15 16 17 18 19]
  ...
[990 991 992 993 994 995 996 997 998 999]
Distinct: 1000

[382 318 466 963 619 22 21 273 45 596]
[808 639 804 471 394 904 952 75 289 778]
  ...
[484 216 622 139 651 592 379 228 242 355]
Distinct: 1000
nil

See also

• List of JVM languages
• List of CLI languages
• Hy

References

Further reading

External links

Official website